TextAddInt - Přidání neformátovaného celého čísla bez znaménka na konec textového řetězce

TextAddInt - Přidání neformátovaného celého čísla bez znaménka na konec textového řetězce

Funkce TextAddInt přidá neformátované celé číslo bez znaménka na konec textového řetězce.


; -----------------------------------------------------------------------------
;             Add unformated unsigned integer number to end of text
; -----------------------------------------------------------------------------
; INPUT:	EAX = unsigned number
;		EBX = pointer to TEXT variable
; OUTPUT:	CY = memory error or invalid number (text not changed)
; -----------------------------------------------------------------------------

Na vstupu funkce obsahuje registr EAX celé číslo bez znaménka. Registr EBX obsahuje ukazatel na textovou proměnnou, ke které se má číslo přidat. V případě chyby paměti je navrácen chybový příznak CY a obsah textové proměnné se nezmění.


; ------------- Push registers

TextAddInt:	push	eax		; push EAX
		push	ecx		; push ECX
		push	edx		; push EDX
		push	esi		; push ESI
		push	edi		; push EDI
		xchg	eax,esi		; ESI <- number

; ------------- Copy text on write

		call	TextCopyWrite	; copy text on write
		jc	TextAddInt8	; memory error

Pomocí funkce TextCopyWrite se provede kopie textu před zápisem. Pokud nastane chyba paměti, funkce se ukončí s chybou a text zůstane nezměněn.


; ------------- Get number of bits in number (-> AL, minimal 1)

		xor	ecx,ecx		; ECX <- 0
		inc	ecx		; ECX <- 1, minimal 1 digit if zero
		bsr	eax,esi		; AL <- highest bit in number
		jz	TextAddInt2	; number is zero, use 1 digit
		inc	eax		; AL <- number of bits in number

Pro konverzi čísla je potřeba znát délku textu, protože dekódování čísla se provádí odzadu. Do registru ECX se přednastaví 1 jako minimální délka čísla pro případ nuly. Instrukcí BSR se vyhledá pozice nejvyššího bitu "1" v čísle. Pokud bylo číslo nula, použije se délka čísla 1. Inkrementací pozice bitu v registru EAX se obdrží počet bitů čísla.


; ------------- Get number of digits (-> ECX) (ln 10/ln 2 = 3.3219)

		mov	ah,78		; AH <- 100h / 3.3219 round up
		mul	ah		; AH <- aprox. number of digits
		movzx	ecx,ah		; ECX <- aprox. number of digits
		cmp	[IntMul10+ecx*4],esi ; check number
		adc	cl,0		; ECX <- number of digits

Z počtu bitů se zjistí počet číslic čísla tak, že počet bitů (což je dvojkový logaritmus čísla) se vydělí konstantou ln 10 / ln 2 = 3.3219, tím se převede na dekadický logaritmus, což znamená počet číslic. Vlivem zaokrouhlení na celá čísla ale tento údaj není ještě přesný, proto se upřesní tak, že se konvertované číslo porovná s hranicemi podle tabulky IntMul10 (obsahující mocniny 10) a počet číslic se opraví na správnou hodnotu.


; ------------- Resize data buffer

TextAddInt2:	mov	eax,[ebx]	; EAX <- data buffer
		mov	eax,[eax+TEXT_Length] ; EAX <- length of data buffer
		add	eax,ecx		; EAX <- add text length
		call	TextResize	; resize data buffer
		jc	TextAddInt8	; memory error
		add	eax,[ebx]	; EAX <- end of data buffer
		add	eax,TEXT_Text-1	; EAX <- last character in buffer
		xchg	eax,edi		; EDI <- end of data buffer

Voláním funkce TextResize se nastaví nová velikost datového bufferu, tj. stará velikost zvýšená o zjištěný počet číslic. Pokud nastane chyba paměti, funkce se ukončí s chybou a text zůstane nezměněn. Do registru EDI se připraví adresa konce datového bufferu.


; ------------- Convert number

		std			; set direction down
TextAddInt4:	mov	eax,3435973837	; EAX <- 800000000h/10, rounded up
		mul	esi		; EDX <- (number*8) / 10
		shr	edx,3		; EDX <- number / 10
		mov	al,10		; AL <- 10
		mul	dl		; AL <- number / 10 * 10 low byte
		xchg	eax,esi		; EAX <- number, ESI <- number low byte
		sub	eax,esi		; AL <- number % 10
		add	al,"0"		; AL <- convert to ASCII character
		stosb			; store one character
		mov	esi,edx		; ESI <- number / 10
		loop	TextAddInt4	; next character
		cld			; set direction up

; ------------- Pop registers

		clc			; clear error flag
TextAddInt8:	pop	edi		; pop EDI
		pop	esi		; pop ESI
		pop	edx		; pop EDX
		pop	ecx		; pop ECX
		pop	eax		; pop EAX
		ret

Nyní je vše již připraveno a může být zahájena konverze čísla na číslice. Konverze se bude provádět od konce bufferu, proto se nastaví příznak směru ukládání dolů.

K získání další (nejnižší) číslice bude číslo vyděleno 10. Pro zrychlení konverze se namísto dělení použije rychlejší operace násobení převrácenou hodnotou. Podíl zůstane v registru EDX. Opětovným vynásobením číslem 10 a odečtením od původního čísla se získá zbytek po dělení. Vzhledem k rozsahu výsledku není třeba dělat plné násobení, stačí jen násobit nejnižší bajt podílu (v registru DL). Zbytek po dělení se přičtením "0" převede na ASCII znak a uloží do bufferu EDI. Poté se pokračuje další číslicí čítáním registru ECX.