OctToTextBufN - Délka textu formátovaného čísla OCT


; -----------------------------------------------------------------------------
;              Convert OCT number into text buffer - get text length
; -----------------------------------------------------------------------------
; INPUT:	EDX:EAX = number
;		EBX = formatting parameters FORMPAR
; OUTPUT:	EAX = text length
; -----------------------------------------------------------------------------

Na vstupu funkce obsahuje registrový pár EDX:EAX číslo bez znaménka ke konverzi a registr EBX formátovací parametry FORMPAR (ne ukazatel). Na výstupu je navrácena v registru EAX délka textu.


OctToTextBufN:	call	Oct0ToTextBufN	; get text length without spaces
		push	ebx		; push EBX
		movzx	ebx,bh		; EBX <- minimal width of field
		cmp	ebx,eax		; check text length
		jb	OctToTextBufN8	; text length is OK
		xchg	eax,ebx		; EAX <- new text length
OctToTextBufN8:	pop	ebx		; pop EBX
OctToTextBufN9:	ret

Funkce OctToTextBufN volá interní funkci Oct0ToTextBufN, která nezapočítává požadovanou šířku pole. Porovnáním s požadovanou minimální šířkou se ověří, zda je délka textu čísla větší než požadovaná minimální šířka. Pokud je menší, navrátí funkce požadovanou minimální šířku namísto délky textu bez mezer.


; -----------------------------------------------------------------------------
;     Convert OCT number into text buffer - get text length without spaces
; -----------------------------------------------------------------------------
; INPUT:	EDX:EAX = number
;		EBX = formatting parameters FORMPAR
; OUTPUT:	EAX = text length
; -----------------------------------------------------------------------------

Funkce Oct0ToTextBufN zjistí délku textu bez uvažování minimální šířky textu. Na vstupu funkce obsahuje registrový pár EDX:EAX číslo bez znaménka ke konverzi a registr EBX formátovací parametry FORMPAR (ne ukazatel). Na výstupu je navrácena v registru EAX délka textu.


; ------------- Push registers

Oct0ToTextBufN:	push	edx		; push EDX
		push	edi		; push EDI

; ------------- Get number of bits in number LOW (-> AL)

		bsr	eax,eax		; AL <- highest bit in number LOW
		setz	ah		; AH <- 1 if EAX == 0, 0 if EAX != 0
		add	al,1		; AL <- number of bits in number LOW
		dec	ah		; AH <- 0 if EAX == 0, 0ffh if EAX != 0
		and	al,ah		; clear AL if number LOW is zero

; ------------- Get number of bits in number HIGH + 32 (-> DL)

		bsr	edx,edx		; DL <- highest bit in number HIGH
		setz	dh		; DH <- 1 if EDX == 0, 0 if EDX != 0
		add	dl,32+1		; DL <- add HIGH correction
		dec	dh		; DH <- 0 if EDX == 0, 0ffh if EDX != 0
		and	dl,dh		; clear DL if number HIGH is zero

; ------------- Put together HIGH and LOW bits (-> EDX)

		not	dh		; DH <- 0ffh if EDX == 0, 0 if EDX != 0
		and	al,dh		; clear AL if number HIGH is not zero
		or	dl,al		; DL <- number of bits in the number

; ------------- Get number of digits in the number (-> EDX)

		add	dl,2		; DL <- round up
		movzx	edx,dl		; EDX <- number of bits
		imul	edx,edx,21846	; EDX <- number of bits * 10000h/3
		shr	edx,16		; EDX <- number of digits

Pro výpočet počtu číslic OCT čísla je nutné nejdříve zjistit pozici nejvyššího bitu v čísle. Číslo má velikost 2 dvojregistry, proto musí být informace sloučena z obou dvojregistrů.

Nejdříve bude vyhledána pozice nejvyššího bitu v registru EAX, který obsahuje nižší část čísla (LOW). Instrukce BSR uloží do registru EAX bitový offset nejvyššího nalezeného bitu 1. Pokud byl obsah registru EAX nulový, nastaví se příznak ZF. To využije následující instrukce SETZ, která uloží do registru AH hodnotu 1 v případě nulového obsahu čísla, jinak do AH uloží 0. Přičtením 1 k AL se obdrží v registru AL počet bitů původního čísla LOW. Avšak pokud byl obsah čísla LOW nulový, je obsah registru AL nedefinovaný. Proto je AL zamaskován maskou vygenerovanou z příznaku ZF v registru AH. Výsledkem je, že registr AL obsahuje buď počet bitů v původní nižší části čísla nebo nulu pokud byla nižší část čísla nulová.

Podobným způsobem je zjištěn počet bitů ve vyšší části čísla (HIGH) s tím rozdílem, že počet bitů je uložen do registru DL a je o 32 vyšší.

Další operací se údaje z nižší a vyšší části čísla sloučí do jednoho údaje. Pokud bylo číslo větší než DWORD, má maska v registru DH hodnotu 0FFh. Pokud se číslo vešlo do nižšího DWORD, má maska v DH hdnotu 0. Proto inverzí masky v DH a zamaskováním počtu bitů v AL z nižší části čísla se počet bitů vynuluje v případě, že číslo bylo větší než DWORD. Následnou instrukcí OR se údaje sloučí do registru DL, který ve výsledku obsahuje počet bitů v registrovém páru EDX:EAX.

Z počtu bitů se odvodí počet oktalových číslic tak, že se počet bitů zaokrouhlí na nejbližší vyšší násobek 3 a výsledek se vydělí 3 (protože jedna OCT číslice zabere 3 bity) . Namísto dělení je použita rychlejší operace násobení převrácenou hodnotou (tj. číslem 10000h/3, zaokrouhleno nahoru), po rotaci výsledku o 16 bitů doprava se obdrží výsledek v registru EDX.


; ------------- Limit minimal number of digits (-> EDX)

		cmp	dl,bl		; check minimal number of digits
		ja	Oct0ToTextBufN2	; number of digits is OK
		mov	dl,bl		; EDX <- minimal numer of digits

Vypočtená délka čísla se zvýší podle požadovaného minimálního počtu číslic (zadaného položkou FORMPAR_Prec formátovacích parametrů).


; ------------- Check if use zeros instead of spaces

Oct0ToTextBufN2:bt	ebx,FORMFLAG_Zero_b ; add zeros instead of spaces?
		jnc	Oct0ToTextBufN6	; no zeros

; ------------- Prepare width of field (-> EAX)

		movzx	eax,bh		; EAX <- minimal width of field
		bt	ebx,FORMFLAG_Alt_b ; use prefix?
		jnc	Oct0ToTextBufN3	; not using prefix
		sub	al,1		; without prefix
		jbe	Oct0ToTextBufN6	; width is low
Oct0ToTextBufN3:bt	ebx,FORMFLAG_Alt2_b ; use suffix?
		jnc	Oct0ToTextBufN4	; not using suffix
		sub	al,1		; without suffix
		jbe	Oct0ToTextBufN6	; width is low

; ------------- New minimal number of digits

Oct0ToTextBufN4:cmp	eax,edx		; check number of digits
		jb	Oct0ToTextBufN6	; number of digits is not greater
		xchg	eax,edx		; EDX <- new text length

Další výpočet musí zajistit doplnění nul k číslu, je-li aktivní příznakový bit FORMFLAG_Zero_b.

Do registru EAX se připraví požadovaná minimální šířka pole (z registru BH, tj. parametr FORMPAR_Width formátovacích parametrů) snížená o případný prefix a sufix. Při malé šířce pole se nuly přidávat nebudou.

Po přípravě počtu číslic potřebných k doplnění čísla nulami se výsledek porovná se skutečnou šířkou čísla a případně se počet číslic zvýší.


; ------------- Add prefix "0"

Oct0ToTextBufN6:bt	ebx,FORMFLAG_Alt_b ; use prefix?
		adc	edx,byte 0	; EDX <- add prefix "0"

Je-li požadován prefix "0" před číslem (je nastaven přepínač FORMFLAG_Alt_b), zvýší se délka textu o 1.


; ------------- Add suffix "o"

		bt	ebx,FORMFLAG_Alt2_b ; use suffix?
		jnc	Oct0ToTextBufN9	; not using suffix
		cmp	edx,byte 1	; check minimal number of digits
		adc	edx,byte 1	; EDX <- add 1 or 2 characters

; ------------- Pop registers

Oct0ToTextBufN9:xchg	eax,edx		; EAX <- text size in characters
		pop	edi		; pop EDI
		pop	edx		; pop EDX
		ret

Je-li požadován sufix "o" za číslem (je nastaven přepínač FORMFLAG_Alt2_b), zvýší se délka textu o 1. Současně je zde zajištěno kontrolou minimálního počtu číslic, aby v případě sufixu mělo číslo alespoň 1 číslici (tj. aby při nule byl text "0o").

OctToTextBuf		Zformátování čísla OCT do bufferu
FormToTextBufN		Délka formátovaného textu